feat: add temperature widgets, separate ram/cpu widgets, update

calculations - make CPU calculations per-process mirror gnome (of all CPUs)
2025-12-06 21:45:38 -05:00 · 2025-08-08 14:43:43 -04:00
parent 105353c2a4
commit 03276b7d9a
27 changed files with 794 additions and 254 deletions
--- a/Modules/TopBar/CpuTemperature.qml
+++ b/Modules/TopBar/CpuTemperature.qml
@@ -0,0 +1,91 @@
+import QtQuick
+import QtQuick.Controls
+import qs.Common
+import qs.Services
+import qs.Widgets
+
+Rectangle {
+    id: root
+
+    property bool showPercentage: true
+    property bool showIcon: true
+    property var toggleProcessList
+    property string section: "right"
+    property var popupTarget: null
+    property var parentScreen: null
+
+    width: 55
+    height: 30
+    radius: Theme.cornerRadius
+    color: {
+        const baseColor = cpuTempArea.containsMouse ? Theme.primaryPressed : Theme.secondaryHover;
+        return Qt.rgba(baseColor.r, baseColor.g, baseColor.b, baseColor.a * Theme.widgetTransparency);
+    }
+    Component.onCompleted: {
+        SysMonitorService.addRef();
+    }
+    Component.onDestruction: {
+        SysMonitorService.removeRef();
+    }
+
+    MouseArea {
+        id: cpuTempArea
+
+        anchors.fill: parent
+        hoverEnabled: true
+        cursorShape: Qt.PointingHandCursor
+        onClicked: {
+            if (popupTarget && popupTarget.setTriggerPosition) {
+                var globalPos = mapToGlobal(0, 0);
+                var currentScreen = parentScreen || Screen;
+                var screenX = currentScreen.x || 0;
+                var relativeX = globalPos.x - screenX;
+                popupTarget.setTriggerPosition(relativeX, Theme.barHeight + Theme.spacingXS, width, section, currentScreen);
+            }
+            SysMonitorService.setSortBy("cpu");
+            if (root.toggleProcessList)
+                root.toggleProcessList();
+        }
+    }
+
+    Row {
+        anchors.centerIn: parent
+        spacing: 3
+
+        DankIcon {
+            name: "memory"
+            size: Theme.iconSize - 8
+            color: {
+                if (SysMonitorService.cpuTemperature > 85)
+                    return Theme.tempDanger;
+
+                if (SysMonitorService.cpuTemperature > 69)
+                    return Theme.tempWarning;
+
+                return Theme.surfaceText;
+            }
+            anchors.verticalCenter: parent.verticalCenter
+        }
+
+        StyledText {
+            text: {
+                if (SysMonitorService.cpuTemperature === undefined || SysMonitorService.cpuTemperature === null || SysMonitorService.cpuTemperature < 0) {
+                    return "--°";
+                }
+                return Math.round(SysMonitorService.cpuTemperature) + "°";
+            }
+            font.pixelSize: Theme.fontSizeSmall
+            font.weight: Font.Medium
+            color: Theme.surfaceText
+            anchors.verticalCenter: parent.verticalCenter
+        }
+
+    }
+
+    Behavior on color {
+        ColorAnimation {
+            duration: Theme.shortDuration
+            easing.type: Theme.standardEasing
+        }
+    }
+}