niri: add spotlight on overview typing functionality (#774)

quickshell/Modules/Settings/LauncherTab.qml

@@ -591,6 +591,72 @@ Item {
                 }
             }
 
+            StyledRect {
+                width: parent.width
+                height: niriOverviewSection.implicitHeight + Theme.spacingL * 2
+                radius: Theme.cornerRadius
+                color: Theme.withAlpha(Theme.surfaceContainerHigh, Theme.popupTransparency)
+                border.color: Qt.rgba(Theme.outline.r, Theme.outline.g,
+                                      Theme.outline.b, 0.2)
+                border.width: 0
+                visible: CompositorService.isNiri
+
+                Column {
+                    id: niriOverviewSection
+
+                    anchors.fill: parent
+                    anchors.margins: Theme.spacingL
+                    spacing: Theme.spacingM
+
+                    Row {
+                        width: parent.width
+                        spacing: Theme.spacingM
+
+                        DankIcon {
+                            name: "open_in_new"
+                            size: Theme.iconSize
+                            color: Theme.primary
+                            anchors.verticalCenter: parent.verticalCenter
+                        }
+
+                        StyledText {
+                            text: I18n.tr("Close Overview on Launch")
+                            font.pixelSize: Theme.fontSizeLarge
+                            font.weight: Font.Medium
+                            color: Theme.surfaceText
+                            anchors.verticalCenter: parent.verticalCenter
+                        }
+
+                        Item {
+                            width: parent.width - parent.children[0].width
+                                   - parent.children[1].width
+                                   - niriOverviewToggle.width - Theme.spacingM * 3
+                            height: 1
+                        }
+
+                        DankToggle {
+                            id: niriOverviewToggle
+
+                            width: 32
+                            height: 18
+                            checked: SettingsData.spotlightCloseNiriOverview
+                            anchors.verticalCenter: parent.verticalCenter
+                            onToggled: checked => {
+                                SettingsData.set("spotlightCloseNiriOverview", checked)
+                            }
+                        }
+                    }
+
+                    StyledText {
+                        width: parent.width
+                        text: I18n.tr("When enabled, launching an app from the launcher will automatically close the Niri overview if it's open.")
+                        font.pixelSize: Theme.fontSizeSmall
+                        color: Theme.surfaceVariantText
+                        wrapMode: Text.WordWrap
+                    }
+                }
+            }
+
             StyledRect {
                 width: parent.width
                 height: recentlyUsedSection.implicitHeight + Theme.spacingL * 2

quickshell/Modules/WorkspaceOverlays/NiriOverviewOverlay.qml

@@ -0,0 +1,117 @@
+import QtQuick
+import QtQuick.Controls
+import Quickshell
+import Quickshell.Wayland
+import qs.Common
+import qs.Services
+
+Scope {
+    id: niriOverviewScope
+
+    // Only show overlay when in overview and spotlight is not open
+    property bool overlayActive: NiriService.inOverview && !(PopoutService.spotlightModal?.spotlightOpen ?? false)
+
+    Loader {
+        id: niriOverlayLoader
+        active: NiriService.inOverview
+        asynchronous: false
+
+        sourceComponent: Variants {
+            id: overlayVariants
+            model: Quickshell.screens
+
+            PanelWindow {
+                id: overlayWindow
+                required property var modelData
+
+                screen: modelData
+                visible: niriOverviewScope.overlayActive
+                color: "transparent"
+
+                WlrLayershell.namespace: "dms:niri-overview-overlay"
+                WlrLayershell.layer: WlrLayer.Overlay
+                WlrLayershell.exclusiveZone: -1
+                WlrLayershell.keyboardFocus: niriOverviewScope.overlayActive ? WlrKeyboardFocus.Exclusive : WlrKeyboardFocus.None
+
+                implicitWidth: 0
+                implicitHeight: 0
+
+                anchors {
+                    top: true
+                    left: true
+                    right: false
+                    bottom: false
+                }
+
+                FocusScope {
+                    id: keyboardFocusScope
+                    anchors.fill: parent
+                    visible: niriOverviewScope.overlayActive
+                    focus: niriOverviewScope.overlayActive
+
+                    Keys.onPressed: event => {
+
+                                        // Handle arrow keys and escape for navigation, mimicking niri's harcoded keybinds
+                                        if ([Qt.Key_Escape, Qt.Key_Return].includes(event.key)) {
+                                            NiriService.toggleOverview()
+                                            event.accepted = true
+                                            return
+                                        }
+
+                                        if (event.key === Qt.Key_Left) {
+                                            NiriService.moveColumnLeft()
+                                            event.accepted = true
+                                            return
+                                        }
+
+                                        if (event.key === Qt.Key_Right) {
+                                            NiriService.moveColumnRight()
+                                            event.accepted = true
+                                            return
+                                        }
+
+                                        if (event.key === Qt.Key_Up) {
+                                            NiriService.moveWorkspaceUp()
+                                            event.accepted = true
+                                            return
+                                        }
+
+                                        if (event.key === Qt.Key_Down) {
+                                            NiriService.moveWorkspaceDown()
+                                            event.accepted = true
+                                            return
+                                        }
+
+                                        // Allowing delete and backspace will produce a broken text
+                                        if (event.modifiers & (Qt.ControlModifier | Qt.MetaModifier) || [Qt.Key_Delete, Qt.Key_Backspace].includes(event.key)) {
+                                            event.accepted = false
+                                            return
+                                        }
+
+                                        // For any other key (printable characters), open spotlight
+                                        if (!event.isAutoRepeat) {
+                                            Qt.callLater(() => {
+                                                             if (PopoutService.spotlightModal) {
+                                                                 if (event.text) {
+                                                                     PopoutService.spotlightModal.showWithQuery(event.text.trim())
+                                                                 }
+                                                             }
+                                                         })
+
+                                            event.accepted = true
+                                        }
+                                    }
+
+                    Connections {
+                        target: niriOverviewScope
+                        function onOverlayActiveChanged() {
+                            if (niriOverviewScope.overlayActive) {
+                                Qt.callLater(() => keyboardFocusScope.forceActiveFocus())
+                            }
+                        }
+                    }
+                }
+            }
+        }
+    }
+}