config refacotr: separate settings.json, session.json, appusage.json

2026-04-03 20:32:07 -04:00 · 2025-08-06 11:47:24 -04:00
parent defc50eec6
commit 18aa557ef1
45 changed files with 639 additions and 529 deletions
--- a/Common/AppUsageHistoryData.qml
+++ b/Common/AppUsageHistoryData.qml
@@ -0,0 +1,128 @@
+pragma Singleton
+pragma ComponentBehavior: Bound
+
+import QtCore
+import QtQuick
+import Quickshell
+import Quickshell.Io
+
+Singleton {
+
+    id: root
+
+    property var appUsageRanking: {}
+
+    readonly property string _configUrl: StandardPaths.writableLocation(StandardPaths.ConfigLocation)
+    readonly property string _configDir: _configUrl.startsWith("file://") ? _configUrl.substring(7) : _configUrl
+
+    Component.onCompleted: {
+        loadSettings();
+    }
+
+    function loadSettings() {
+        parseSettings(settingsFile.text());
+    }
+
+    function parseSettings(content) {
+        try {
+            if (content && content.trim()) {
+                var settings = JSON.parse(content);
+                appUsageRanking = settings.appUsageRanking || {};
+            }
+        } catch (e) {
+        }
+    }
+
+    function saveSettings() {
+        settingsFile.setText(JSON.stringify({
+            "appUsageRanking": appUsageRanking
+        }, null, 2));
+    }
+
+    function addAppUsage(app) {
+        if (!app)
+            return;
+
+        var appId = app.id || (app.execString || app.exec || "");
+        if (!appId)
+            return;
+
+        var currentRanking = Object.assign({}, appUsageRanking);
+        
+        if (currentRanking[appId]) {
+            currentRanking[appId].usageCount = (currentRanking[appId].usageCount || 1) + 1;
+            currentRanking[appId].lastUsed = Date.now();
+            currentRanking[appId].icon = app.icon || currentRanking[appId].icon || "application-x-executable";
+            currentRanking[appId].name = app.name || currentRanking[appId].name || "";
+        } else {
+            currentRanking[appId] = {
+                "name": app.name || "",
+                "exec": app.execString || app.exec || "",
+                "icon": app.icon || "application-x-executable",
+                "comment": app.comment || "",
+                "usageCount": 1,
+                "lastUsed": Date.now()
+            };
+        }
+        
+        appUsageRanking = currentRanking;
+        saveSettings();
+    }
+
+    function getAppUsageRanking() {
+        return appUsageRanking;
+    }
+
+    function getRankedApps() {
+        var apps = [];
+        for (var appId in appUsageRanking) {
+            var appData = appUsageRanking[appId];
+            apps.push({
+                id: appId,
+                name: appData.name,
+                exec: appData.exec,
+                icon: appData.icon,
+                comment: appData.comment,
+                usageCount: appData.usageCount,
+                lastUsed: appData.lastUsed
+            });
+        }
+        
+        return apps.sort(function(a, b) {
+            if (a.usageCount !== b.usageCount)
+                return b.usageCount - a.usageCount;
+            return a.name.localeCompare(b.name);
+        });
+    }
+
+    function cleanupAppUsageRanking(availableAppIds) {
+        var currentRanking = Object.assign({}, appUsageRanking);
+        var hasChanges = false;
+        
+        for (var appId in currentRanking) {
+            if (availableAppIds.indexOf(appId) === -1) {
+                delete currentRanking[appId];
+                hasChanges = true;
+            }
+        }
+        
+        if (hasChanges) {
+            appUsageRanking = currentRanking;
+            saveSettings();
+        }
+    }
+
+    FileView {
+        id: settingsFile
+
+        path: StandardPaths.writableLocation(StandardPaths.ConfigLocation) + "/DankMaterialShell/appusage.json"
+        blockLoading: true
+        blockWrites: true
+        watchChanges: true
+        onLoaded: {
+            parseSettings(settingsFile.text());
+        }
+        onLoadFailed: (error) => {
+        }
+    }
+}