Refactor shadow handling & improve connected chrome rendering

quickshell/Common/ElevationShadow.qml

@@ -1,7 +1,6 @@
 pragma ComponentBehavior: Bound
 
 import QtQuick
-import QtQuick.Effects
 import qs.Common
 
 Item {
@@ -19,7 +18,12 @@ Item {
     property real bottomRightRadius: targetRadius
     property color borderColor: "transparent"
     property real borderWidth: 0
-    property bool useCustomSource: false
+
+    // Rounded-rect geometry within the item; defaults fill the item.
+    property real sourceX: 0
+    property real sourceY: 0
+    property real sourceWidth: width
+    property real sourceHeight: height
 
     property bool shadowEnabled: Theme.elevationEnabled
     property real shadowBlurPx: level && level.blurPx !== undefined ? level.blurPx : 0
@@ -28,36 +32,26 @@ Item {
     property real shadowOffsetY: Theme.elevationOffsetYFor(level, direction, fallbackOffset)
     property color shadowColor: Theme.elevationShadowColor(level)
     property real shadowOpacity: 1
-    property real blurMax: Theme.elevationBlurMax
 
-    property alias sourceRect: sourceRect
+    readonly property var _ambient: Theme.elevationAmbient(level)
+    readonly property real _pad: shadowEnabled ? Math.ceil(Math.max(shadowBlurPx + shadowSpreadPx + Math.max(Math.abs(shadowOffsetX), Math.abs(shadowOffsetY)), _ambient.blurPx + _ambient.spreadPx) + 2) : 0
 
-    layer.enabled: shadowEnabled
-
-    layer.effect: MultiEffect {
-        autoPaddingEnabled: true
-        shadowEnabled: true
-        blurEnabled: false
-        maskEnabled: false
-        shadowBlur: Math.max(0, Math.min(1, root.shadowBlurPx / Math.max(1, root.blurMax)))
-        shadowScale: 1 + (2 * root.shadowSpreadPx) / Math.max(1, Math.min(root.width, root.height))
-        shadowHorizontalOffset: root.shadowOffsetX
-        shadowVerticalOffset: root.shadowOffsetY
-        blurMax: root.blurMax
-        shadowColor: root.shadowColor
-        shadowOpacity: root.shadowOpacity
-    }
-
-    Rectangle {
-        id: sourceRect
+    // Fill + border + key/ambient shadows drawn analytically on one oversized
+    // quad — no FBO, no blur passes.
+    ShaderEffect {
         anchors.fill: parent
-        visible: !root.useCustomSource
-        topLeftRadius: root.topLeftRadius
-        topRightRadius: root.topRightRadius
-        bottomLeftRadius: root.bottomLeftRadius
-        bottomRightRadius: root.bottomRightRadius
-        color: root.targetColor
-        border.color: root.borderColor
-        border.width: root.borderWidth
+        anchors.margins: -root._pad
+        fragmentShader: Qt.resolvedUrl("../Shaders/qsb/elevation_rect.frag.qsb")
+
+        property real widthPx: width
+        property real heightPx: height
+        property real borderWidth: root.borderWidth
+        property vector4d rectPx: Qt.vector4d(root._pad + root.sourceX, root._pad + root.sourceY, root.sourceWidth, root.sourceHeight)
+        property vector4d cornerRadius: Qt.vector4d(root.topLeftRadius, root.topRightRadius, root.bottomRightRadius, root.bottomLeftRadius)
+        property vector4d fillColor: Qt.vector4d(root.targetColor.r, root.targetColor.g, root.targetColor.b, root.targetColor.a)
+        property vector4d borderColor: Qt.vector4d(root.borderColor.r, root.borderColor.g, root.borderColor.b, root.borderColor.a)
+        property vector4d shadowColor: Qt.vector4d(root.shadowColor.r, root.shadowColor.g, root.shadowColor.b, root.shadowEnabled ? root.shadowColor.a * root.shadowOpacity : 0)
+        property vector4d shadowParam: Qt.vector4d(Math.max(0, root.shadowBlurPx), root.shadowSpreadPx, root.shadowOffsetX, root.shadowOffsetY)
+        property vector4d ambientParam: Qt.vector4d(root._ambient.blurPx, root._ambient.spreadPx, root.shadowEnabled ? root._ambient.alpha * root.shadowOpacity : 0, 0)
     }
 }

quickshell/Common/Theme.qml

@@ -911,6 +911,19 @@ Singleton {
         }
         return Qt.rgba(r, g, b, alpha);
     }
+    // Non-directional ambient layer of the M3 two-part shadow model (key +
+    // ambient). Derived from the key level so user intensity/opacity settings
+    // scale both layers together.
+    function elevationAmbient(level) {
+        const blur = (level && level.blurPx !== undefined) ? Math.max(0, level.blurPx) : 0;
+        const alpha = ((level && level.alpha !== undefined) ? level.alpha : 0.3) * 0.5;
+        return {
+            blurPx: blur * 1.75,
+            spreadPx: 1,
+            alpha: alpha
+        };
+    }
+
     function elevationTintOpacity(level) {
         if (!level)
             return 0;