dock: add trash CLI, refine implementation

quickshell/Modals/FileBrowser/FileBrowserContent.qml

@@ -158,6 +158,13 @@ FocusScope {
         selectedFileIsDir = isDir;
     }
 
+    function openItemContextMenu(sender, localX, localY, path, name, isDir) {
+        if (!sender)
+            return;
+        const pos = sender.mapToItem(root, localX, localY);
+        itemContextMenu.showAt(root, pos.x, pos.y, path, name, isDir);
+    }
+
     function navigateUp() {
         const path = currentPath;
         if (path === homeDir)
@@ -759,6 +766,9 @@ FocusScope {
                                 onItemSelected: (index, path, name, isDir) => {
                                     setSelectedFileData(path, name, isDir);
                                 }
+                                onItemContextMenuRequested: (sender, localX, localY, path, name, isDir) => {
+                                    root.openItemContextMenu(sender, localX, localY, path, name, isDir);
+                                }
 
                                 Connections {
                                     function onKeyboardSelectionRequestedChanged() {
@@ -817,6 +827,9 @@ FocusScope {
                                 onItemSelected: (index, path, name, isDir) => {
                                     setSelectedFileData(path, name, isDir);
                                 }
+                                onItemContextMenuRequested: (sender, localX, localY, path, name, isDir) => {
+                                    root.openItemContextMenu(sender, localX, localY, path, name, isDir);
+                                }
 
                                 Connections {
                                     function onKeyboardSelectionRequestedChanged() {
@@ -917,4 +930,9 @@ FocusScope {
             }
         }
     }
+
+    FileBrowserItemContextMenu {
+        id: itemContextMenu
+        parentFocusItem: root
+    }
 }

quickshell/Modals/FileBrowser/FileBrowserGridDelegate.qml

@@ -19,6 +19,7 @@ StyledRect {
 
     signal itemClicked(int index, string path, string name, bool isDir)
     signal itemSelected(int index, string path, string name, bool isDir)
+    signal itemContextMenuRequested(var sender, real localX, real localY, string path, string name, bool isDir)
 
     function getFileExtension(fileName) {
         const parts = fileName.split('.');
@@ -107,11 +108,11 @@ StyledRect {
         const size = _thumbnailPx;
         const fp = delegateRoot.filePath;
         Paths.mkdir(thumbDir);
-        Proc.runCommand(null, ["test", "-f", thumbPath], function(output, exitCode) {
+        Proc.runCommand(null, ["test", "-f", thumbPath], function (output, exitCode) {
             if (exitCode === 0) {
                 _videoThumb = thumbPath;
             } else {
-                Proc.runCommand(null, ["ffmpegthumbnailer", "-i", fp, "-o", thumbPath, "-s", String(size), "-f"], function(output, exitCode) {
+                Proc.runCommand(null, ["ffmpegthumbnailer", "-i", fp, "-o", thumbPath, "-s", String(size), "-f"], function (output, exitCode) {
                     if (exitCode === 0)
                         _videoThumb = thumbPath;
                 });
@@ -246,8 +247,16 @@ StyledRect {
         anchors.fill: parent
         hoverEnabled: true
         cursorShape: Qt.PointingHandCursor
-        onClicked: {
-            itemClicked(delegateRoot.index, delegateRoot.filePath, delegateRoot.fileName, delegateRoot.fileIsDir);
+        acceptedButtons: Qt.LeftButton | Qt.RightButton
+        onClicked: mouse => {
+            switch (mouse.button) {
+            case Qt.LeftButton:
+                itemClicked(delegateRoot.index, delegateRoot.filePath, delegateRoot.fileName, delegateRoot.fileIsDir);
+                break;
+            case Qt.RightButton:
+                itemContextMenuRequested(delegateRoot, mouse.x, mouse.y, delegateRoot.filePath, delegateRoot.fileName, delegateRoot.fileIsDir);
+                break;
+            }
         }
     }
 }

quickshell/Modals/FileBrowser/FileBrowserItemContextMenu.qml

@@ -0,0 +1,153 @@
+import QtQuick
+import QtQuick.Controls
+import Quickshell
+import qs.Common
+import qs.Services
+import qs.Widgets
+
+Popup {
+    id: root
+
+    property string filePath: ""
+    property string fileName: ""
+    property bool fileIsDir: false
+    property var parentFocusItem: null
+
+    signal trashed
+    signal menuClosed
+
+    readonly property var menuItems: [
+        {
+            text: I18n.tr("Move to Trash"),
+            icon: "delete",
+            action: trashItem,
+            enabled: filePath.length > 0,
+            dangerous: true
+        },
+        {
+            text: I18n.tr("Copy Path"),
+            icon: "content_copy",
+            action: copyPath,
+            enabled: filePath.length > 0
+        }
+    ]
+
+    function showAt(parentItem, localX, localY, path, name, isDir) {
+        if (!parentItem)
+            return;
+        parent = parentItem;
+        filePath = path || "";
+        fileName = name || "";
+        fileIsDir = !!isDir;
+        x = Math.max(0, Math.min(parentItem.width - width, localX));
+        y = Math.max(0, Math.min(parentItem.height - height, localY));
+        open();
+    }
+
+    function trashItem() {
+        if (!filePath)
+            return;
+        TrashService.trashPath(filePath, ok => {
+            if (ok)
+                root.trashed();
+        });
+        close();
+    }
+
+    function copyPath() {
+        if (!filePath)
+            return;
+        Quickshell.execDetached(["dms", "cl", "copy", filePath]);
+        close();
+    }
+
+    width: 220
+    height: menuColumn.implicitHeight + Theme.spacingS * 2
+    padding: 0
+    modal: false
+    closePolicy: Popup.CloseOnEscape
+
+    onClosed: {
+        closePolicy = Popup.CloseOnEscape;
+        menuClosed();
+        if (parentFocusItem)
+            Qt.callLater(() => parentFocusItem.forceActiveFocus());
+    }
+
+    onOpened: outsideClickTimer.start()
+
+    Timer {
+        id: outsideClickTimer
+        interval: 100
+        onTriggered: root.closePolicy = Popup.CloseOnEscape | Popup.CloseOnPressOutside
+    }
+
+    background: Rectangle {
+        color: "transparent"
+    }
+
+    contentItem: Rectangle {
+        color: Theme.floatingSurface
+        radius: Theme.cornerRadius
+        border.color: BlurService.enabled ? BlurService.borderColor : Qt.rgba(Theme.outline.r, Theme.outline.g, Theme.outline.b, 0.08)
+        border.width: BlurService.enabled ? BlurService.borderWidth : 1
+
+        Column {
+            id: menuColumn
+            anchors.fill: parent
+            anchors.margins: Theme.spacingS
+            spacing: 1
+
+            Repeater {
+                model: root.menuItems
+
+                Rectangle {
+                    width: parent.width
+                    height: 32
+                    radius: Theme.cornerRadius
+                    opacity: modelData.enabled ? 1 : 0.5
+                    color: {
+                        if (!modelData.enabled || !area.containsMouse)
+                            return "transparent";
+                        if (modelData.dangerous)
+                            return Qt.rgba(Theme.error.r, Theme.error.g, Theme.error.b, 0.12);
+                        return BlurService.hoverColor(Theme.widgetBaseHoverColor);
+                    }
+
+                    Row {
+                        anchors.left: parent.left
+                        anchors.leftMargin: Theme.spacingS
+                        anchors.right: parent.right
+                        anchors.rightMargin: Theme.spacingS
+                        anchors.verticalCenter: parent.verticalCenter
+                        spacing: Theme.spacingS
+
+                        DankIcon {
+                            anchors.verticalCenter: parent.verticalCenter
+                            name: modelData.icon
+                            size: 16
+                            color: modelData.dangerous && area.containsMouse && modelData.enabled ? Theme.error : Theme.surfaceText
+                        }
+
+                        StyledText {
+                            anchors.verticalCenter: parent.verticalCenter
+                            text: modelData.text
+                            font.pixelSize: Theme.fontSizeSmall
+                            color: modelData.dangerous && area.containsMouse && modelData.enabled ? Theme.error : Theme.surfaceText
+                            elide: Text.ElideRight
+                        }
+                    }
+
+                    MouseArea {
+                        id: area
+                        anchors.fill: parent
+                        hoverEnabled: true
+                        enabled: modelData.enabled
+                        cursorShape: Qt.PointingHandCursor
+                        onClicked: modelData.action()
+                    }
+                }
+            }
+        }
+    }
+}

quickshell/Modals/FileBrowser/FileBrowserListDelegate.qml

@@ -18,6 +18,7 @@ StyledRect {
 
     signal itemClicked(int index, string path, string name, bool isDir)
     signal itemSelected(int index, string path, string name, bool isDir)
+    signal itemContextMenuRequested(var sender, real localX, real localY, string path, string name, bool isDir)
 
     function getFileExtension(fileName) {
         const parts = fileName.split('.');
@@ -102,11 +103,11 @@ StyledRect {
         const thumbPath = videoThumbnailPath;
         const fp = listDelegateRoot.filePath;
         Paths.mkdir(_xdgCacheHome + "/thumbnails/normal");
-        Proc.runCommand(null, ["test", "-f", thumbPath], function(output, exitCode) {
+        Proc.runCommand(null, ["test", "-f", thumbPath], function (output, exitCode) {
             if (exitCode === 0) {
                 _videoThumb = thumbPath;
             } else {
-                Proc.runCommand(null, ["ffmpegthumbnailer", "-i", fp, "-o", thumbPath, "-s", "128", "-f"], function(output, exitCode) {
+                Proc.runCommand(null, ["ffmpegthumbnailer", "-i", fp, "-o", thumbPath, "-s", "128", "-f"], function (output, exitCode) {
                     if (exitCode === 0)
                         _videoThumb = thumbPath;
                 });
@@ -251,8 +252,16 @@ StyledRect {
         anchors.fill: parent
         hoverEnabled: true
         cursorShape: Qt.PointingHandCursor
-        onClicked: {
-            itemClicked(listDelegateRoot.index, listDelegateRoot.filePath, listDelegateRoot.fileName, listDelegateRoot.fileIsDir);
+        acceptedButtons: Qt.LeftButton | Qt.RightButton
+        onClicked: mouse => {
+            switch (mouse.button) {
+            case Qt.LeftButton:
+                itemClicked(listDelegateRoot.index, listDelegateRoot.filePath, listDelegateRoot.fileName, listDelegateRoot.fileIsDir);
+                break;
+            case Qt.RightButton:
+                itemContextMenuRequested(listDelegateRoot, mouse.x, mouse.y, listDelegateRoot.filePath, listDelegateRoot.fileName, listDelegateRoot.fileIsDir);
+                break;
+            }
         }
     }
 }