changelog: capability to display new release message

2026-01-28 23:42:51 -05:00 · 2026-01-07 20:15:50 -05:00
parent 646d60dcbf
commit a5e107c89d
6 changed files with 619 additions and 2 deletions
--- a/quickshell/Services/ChangelogService.qml
+++ b/quickshell/Services/ChangelogService.qml
@@ -0,0 +1,90 @@
+pragma Singleton
+pragma ComponentBehavior: Bound
+
+import QtCore
+import QtQuick
+import Quickshell
+import Quickshell.Io
+import qs.Common
+
+Singleton {
+    id: root
+
+    readonly property string currentVersion: "1.2"
+    readonly property bool changelogEnabled: false
+
+    readonly property string configDir: Paths.strip(StandardPaths.writableLocation(StandardPaths.ConfigLocation)) + "/DankMaterialShell"
+    readonly property string changelogMarkerPath: configDir + "/.changelog-" + currentVersion
+
+    property bool checkComplete: false
+    property bool changelogDismissed: false
+
+    readonly property bool shouldShowChangelog: {
+        if (!checkComplete)
+            return false;
+        if (!changelogEnabled)
+            return false;
+        if (changelogDismissed)
+            return false;
+        if (typeof FirstLaunchService !== "undefined" && FirstLaunchService.isFirstLaunch)
+            return false;
+        return true;
+    }
+
+    signal changelogRequested
+    signal changelogCompleted
+
+    Component.onCompleted: {
+        if (!changelogEnabled)
+            return;
+        changelogCheckProcess.running = true;
+    }
+
+    function showChangelog() {
+        changelogRequested();
+    }
+
+    function dismissChangelog() {
+        changelogDismissed = true;
+        touchMarkerProcess.running = true;
+        changelogCompleted();
+    }
+
+    Process {
+        id: changelogCheckProcess
+
+        command: ["sh", "-c", "[ -f '" + changelogMarkerPath + "' ] && echo 'seen' || echo 'show'"]
+        running: false
+
+        stdout: SplitParser {
+            onRead: data => {
+                const result = data.trim();
+                root.checkComplete = true;
+
+                switch (result) {
+                case "seen":
+                    root.changelogDismissed = true;
+                    break;
+                case "show":
+                    if (typeof FirstLaunchService === "undefined" || !FirstLaunchService.isFirstLaunch) {
+                        root.changelogRequested();
+                    }
+                    break;
+                }
+            }
+        }
+    }
+
+    Process {
+        id: touchMarkerProcess
+
+        command: ["sh", "-c", "mkdir -p '" + configDir + "' && touch '" + changelogMarkerPath + "'"]
+        running: false
+
+        onExited: exitCode => {
+            if (exitCode !== 0) {
+                console.warn("ChangelogService: Failed to create changelog marker");
+            }
+        }
+    }
+}