Add an ArchUpdater widget (#201)

Modules/TopBar/ArchUpdater.qml

@@ -0,0 +1,110 @@
+import QtQuick
+import qs.Common
+import qs.Services
+import qs.Widgets
+
+Rectangle {
+    id: root
+
+    property bool isActive: false
+    property string section: "right"
+    property var popupTarget: null
+    property var parentScreen: null
+    property real widgetHeight: 30
+    property real barHeight: 48
+    readonly property real horizontalPadding: SettingsData.topBarNoBackground ? 0 : Math.max(Theme.spacingXS, Theme.spacingS * (widgetHeight / 30))
+    readonly property bool hasUpdates: ArchUpdaterService.updateCount > 0
+    readonly property bool isChecking: ArchUpdaterService.isChecking
+
+    signal clicked()
+
+    width: updaterIcon.width + horizontalPadding * 2
+    height: widgetHeight
+    radius: SettingsData.topBarNoBackground ? 0 : Theme.cornerRadius
+    color: {
+        if (SettingsData.topBarNoBackground) {
+            return "transparent";
+        }
+
+        const baseColor = updaterArea.containsMouse || root.isActive ? Theme.primaryPressed : Theme.secondaryHover;
+        return Qt.rgba(baseColor.r, baseColor.g, baseColor.b, baseColor.a * Theme.widgetTransparency);
+    }
+
+    Row {
+        id: updaterIcon
+
+        anchors.centerIn: parent
+        spacing: Theme.spacingXS
+
+        DankIcon {
+            id: statusIcon
+
+            anchors.verticalCenter: parent.verticalCenter
+            name: {
+                if (isChecking) return "refresh";
+                if (ArchUpdaterService.hasError) return "error";
+                if (hasUpdates) return "system_update_alt";
+                return "check_circle";
+            }
+            size: Theme.iconSize - 6
+            color: {
+                if (ArchUpdaterService.hasError) return Theme.error;
+                if (hasUpdates) return Theme.primary;
+                return (updaterArea.containsMouse || root.isActive ? Theme.primary : Theme.surfaceText);
+            }
+
+            RotationAnimation {
+                id: rotationAnimation
+                target: statusIcon
+                property: "rotation"
+                from: 0
+                to: 360
+                duration: 1000
+                running: isChecking
+                loops: Animation.Infinite
+
+                onRunningChanged: {
+                    if (!running) {
+                        statusIcon.rotation = 0
+                    }
+                }
+            }
+        }
+
+        StyledText {
+            id: countText
+
+            anchors.verticalCenter: parent.verticalCenter
+            text: ArchUpdaterService.updateCount.toString()
+            font.pixelSize: Theme.fontSizeSmall
+            font.weight: Font.Medium
+            color: Theme.surfaceText
+            visible: hasUpdates && !isChecking
+        }
+    }
+
+    MouseArea {
+        id: updaterArea
+
+        anchors.fill: parent
+        hoverEnabled: true
+        cursorShape: Qt.PointingHandCursor
+        onPressed: {
+            if (popupTarget && popupTarget.setTriggerPosition) {
+                const globalPos = mapToGlobal(0, 0);
+                const currentScreen = parentScreen || Screen;
+                const screenX = currentScreen.x || 0;
+                const relativeX = globalPos.x - screenX;
+                popupTarget.setTriggerPosition(relativeX, barHeight + Theme.spacingXS, width, section, currentScreen);
+            }
+            root.clicked();
+        }
+    }
+
+    Behavior on color {
+        ColorAnimation {
+            duration: Theme.shortDuration
+            easing.type: Theme.standardEasing
+        }
+    }
+}

Modules/TopBar/TopBar.qml

@@ -183,6 +183,9 @@ PanelWindow {
                              }, {
                                  "loader": clipboardHistoryModalPopup,
                                  "prop": "visible"
+                             }, {
+                                 "loader": archUpdaterLoader,
+                                 "prop": "shouldBeVisible"
                              }]
             return notepadInstanceVisible || loaders.some(item => {
                 if (item.loader) {
@@ -373,7 +376,8 @@ PanelWindow {
                                                                  "keyboard_layout_name": keyboardLayoutNameComponent,
                                                                  "vpn": vpnComponent,
                                                                  "notepadButton": notepadButtonComponent,
-                                                                 "colorPicker": colorPickerComponent
+                                                                 "colorPicker": colorPickerComponent,
+                                                                 "archUpdater": archUpdaterComponent
                                                              })
 
                         function getWidgetComponent(widgetId) {
@@ -1016,6 +1020,26 @@ PanelWindow {
                                 }
                             }
                         }
+
+                        Component {
+                            id: archUpdaterComponent
+
+                            ArchUpdater {
+                                isActive: archUpdaterLoader.item ? archUpdaterLoader.item.shouldBeVisible : false
+                                widgetHeight: root.widgetHeight
+                                barHeight: root.effectiveBarHeight
+                                section: topBarContent.getWidgetSection(parent) || "right"
+                                popupTarget: {
+                                    archUpdaterLoader.active = true
+                                    return archUpdaterLoader.item
+                                }
+                                parentScreen: root.screen
+                                onClicked: {
+                                    archUpdaterLoader.active = true
+                                    archUpdaterLoader.item?.toggle()
+                                }
+                            }
+                        }
                     }
                 }
             }