blur: add blur support with ext-bg-effect

quickshell/Modules/DankBar/DankBarWindow.qml

@@ -97,6 +97,112 @@ PanelWindow {
         }
     }
 
+    property var blurRegion: null
+    property var _blurWidgetItems: []
+
+    function registerBlurWidget(item) {
+        if (_blurWidgetItems.indexOf(item) >= 0)
+            return;
+        _blurWidgetItems = _blurWidgetItems.concat([item]);
+        _blurRebuildTimer.restart();
+    }
+
+    function unregisterBlurWidget(item) {
+        const idx = _blurWidgetItems.indexOf(item);
+        if (idx < 0)
+            return;
+        const arr = _blurWidgetItems.slice();
+        arr.splice(idx, 1);
+        _blurWidgetItems = arr;
+        _blurRebuildTimer.restart();
+    }
+
+    Timer {
+        id: _blurRebuildTimer
+        interval: 1
+        onTriggered: barBlur.rebuild()
+    }
+
+    Item {
+        id: barBlur
+        visible: false
+
+        readonly property bool barHasTransparency: barWindow._backgroundAlpha > 0 && barWindow._backgroundAlpha < 1
+
+        function rebuild() {
+            teardown();
+            if (!BlurService.enabled || !BlurService.available)
+                return;
+
+            const widgets = barWindow._blurWidgetItems.filter(w => w && w.visible && w.width > 0 && w.height > 0);
+            const hasBar = barHasTransparency;
+            if (!hasBar && widgets.length === 0)
+                return;
+
+            const cr = Theme.cornerRadius;
+            let qml = 'import QtQuick; import Quickshell; Region {';
+            for (let i = 0; i < widgets.length; i++) {
+                qml += ` property Item w${i}; Region { item: w${i}; radius: ${cr} }`;
+            }
+            qml += '}';
+
+            try {
+                const region = Qt.createQmlObject(qml, barWindow, "BarBlurRegion");
+
+                if (hasBar) {
+                    region.x = Qt.binding(() => topBarMouseArea.x + barUnitInset.x + topBarSlide.x);
+                    region.y = Qt.binding(() => topBarMouseArea.y + barUnitInset.y + topBarSlide.y);
+                    region.width = Qt.binding(() => barUnitInset.width);
+                    region.height = Qt.binding(() => barUnitInset.height);
+                    region.radius = Qt.binding(() => barBackground.rt);
+                }
+
+                for (let i = 0; i < widgets.length; i++) {
+                    region[`w${i}`] = widgets[i];
+                }
+
+                barWindow.BackgroundEffect.blurRegion = region;
+                barWindow.blurRegion = region;
+            } catch (e) {
+                console.warn("BarBlur: Failed to create blur region:", e);
+            }
+        }
+
+        function teardown() {
+            if (!barWindow.blurRegion)
+                return;
+            try {
+                barWindow.BackgroundEffect.blurRegion = null;
+            } catch (e) {}
+            barWindow.blurRegion.destroy();
+            barWindow.blurRegion = null;
+        }
+
+        onBarHasTransparencyChanged: _blurRebuildTimer.restart()
+
+        Connections {
+            target: BlurService
+            function onEnabledChanged() {
+                barBlur.rebuild();
+            }
+        }
+
+        Connections {
+            target: topBarSlide
+            function onXChanged() {
+                if (barWindow.blurRegion)
+                    barWindow.blurRegion.changed();
+            }
+            function onYChanged() {
+                if (barWindow.blurRegion)
+                    barWindow.blurRegion.changed();
+            }
+        }
+
+        Component.onCompleted: rebuild()
+        Component.onDestruction: teardown()
+    }
+
     WlrLayershell.layer: dBarLayer
     WlrLayershell.namespace: "dms:bar"
 
@@ -711,7 +817,8 @@ PanelWindow {
         onHasActivePopoutChanged: evaluateReveal()
 
         function updateActivePopoutState() {
-            if (!barWindow.screen) return;
+            if (!barWindow.screen)
+                return;
             const screenName = barWindow.screen.name;
             const activePopout = PopoutManager.currentPopoutsByScreen[screenName];
             const activeTrayMenu = TrayMenuManager.activeTrayMenus[screenName];