mirror of
https://github.com/AvengeMedia/DankMaterialShell.git
synced 2025-12-05 21:15:38 -05:00
a4a59fd586
- Add surface shift option, start from surface by default (previously was surfaceContainer). Old colors can be attained by changing it back to "container" in theme colors - Remove borders on surface elements, mostly - Fix popup distances - Use surfaceContainer/sch by default on widgets
81 lines
2.6 KiB
QML
81 lines
2.6 KiB
QML
import QtQuick
|
|
import QtQuick.Controls
|
|
import Quickshell
|
|
import Quickshell.Services.Pipewire
|
|
import qs.Common
|
|
import qs.Services
|
|
import qs.Widgets
|
|
|
|
Row {
|
|
id: root
|
|
|
|
property var defaultSource: AudioService.source
|
|
property color sliderTrackColor: "transparent"
|
|
|
|
height: 40
|
|
spacing: 0
|
|
|
|
Rectangle {
|
|
width: Theme.iconSize + Theme.spacingS * 2
|
|
height: Theme.iconSize + Theme.spacingS * 2
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
radius: (Theme.iconSize + Theme.spacingS * 2) / 2
|
|
color: iconArea.containsMouse ? Qt.rgba(Theme.primary.r, Theme.primary.g, Theme.primary.b, 0.12) : "transparent"
|
|
|
|
Behavior on color {
|
|
ColorAnimation { duration: Theme.shortDuration }
|
|
}
|
|
|
|
MouseArea {
|
|
id: iconArea
|
|
anchors.fill: parent
|
|
visible: defaultSource !== null
|
|
hoverEnabled: true
|
|
cursorShape: Qt.PointingHandCursor
|
|
onClicked: {
|
|
if (defaultSource) {
|
|
defaultSource.audio.muted = !defaultSource.audio.muted
|
|
}
|
|
}
|
|
}
|
|
|
|
DankIcon {
|
|
anchors.centerIn: parent
|
|
name: {
|
|
if (!defaultSource) return "mic_off"
|
|
|
|
let volume = defaultSource.audio.volume
|
|
let muted = defaultSource.audio.muted
|
|
|
|
if (muted || volume === 0.0) return "mic_off"
|
|
return "mic"
|
|
}
|
|
size: Theme.iconSize
|
|
color: defaultSource && !defaultSource.audio.muted && defaultSource.audio.volume > 0 ? Theme.primary : Theme.surfaceText
|
|
}
|
|
}
|
|
|
|
DankSlider {
|
|
readonly property real actualVolumePercent: defaultSource ? Math.round(defaultSource.audio.volume * 100) : 0
|
|
|
|
anchors.verticalCenter: parent.verticalCenter
|
|
width: parent.width - (Theme.iconSize + Theme.spacingS * 2)
|
|
enabled: defaultSource !== null
|
|
minimum: 0
|
|
maximum: 100
|
|
value: defaultSource ? Math.min(100, Math.round(defaultSource.audio.volume * 100)) : 0
|
|
showValue: true
|
|
unit: "%"
|
|
valueOverride: actualVolumePercent
|
|
thumbOutlineColor: Theme.surfaceContainer
|
|
trackColor: root.sliderTrackColor.a > 0 ? root.sliderTrackColor : Theme.surfaceContainerHigh
|
|
onSliderValueChanged: function(newValue) {
|
|
if (defaultSource) {
|
|
defaultSource.audio.volume = newValue / 100.0
|
|
if (newValue > 0 && defaultSource.audio.muted) {
|
|
defaultSource.audio.muted = false
|
|
}
|
|
}
|
|
}
|
|
}
|
|
} |