DankMaterialShell/Modules/Notifications/Center/NotificationCenterPopout.qml

import QtQuick
import QtQuick.Controls
import QtQuick.Effects
import Quickshell
import Quickshell.Wayland
import Quickshell.Widgets
import qs.Common
import qs.Services
import qs.Widgets
import qs.Modules.Notifications.Center

DankPopout {
  id: root

  property bool notificationHistoryVisible: false
  property string triggerSection: "right"
  property var triggerScreen: null
  
  NotificationKeyboardController {
    id: keyboardController
    listView: null
    isOpen: notificationHistoryVisible
    onClose: function() { notificationHistoryVisible = false }
  }
  

  function setTriggerPosition(x, y, width, section, screen) {
    triggerX = x
    triggerY = y
    triggerWidth = width
    triggerSection = section
    triggerScreen = screen
  }

  popupWidth: 400
  popupHeight: contentLoader.item ? contentLoader.item.implicitHeight : 400
  triggerX: Screen.width - 400 - Theme.spacingL
  triggerY: Theme.barHeight - 4 + SettingsData.topBarSpacing + Theme.spacingXS
  triggerWidth: 40
  positioning: "center"
  WlrLayershell.namespace: "quickshell-notifications"
  screen: triggerScreen
  shouldBeVisible: notificationHistoryVisible
  visible: shouldBeVisible

  onNotificationHistoryVisibleChanged: {
    if (notificationHistoryVisible) {
      open()
      NotificationService.disablePopups(true)
    } else {
      close()
      NotificationService.disablePopups(false)
    }
  }

  content: Component {
    Rectangle {
      id: notificationContent
      
      implicitHeight: {
        let baseHeight = Theme.spacingL * 2
        baseHeight += notificationHeader.height
        baseHeight += (notificationSettings.expanded ? notificationSettings.contentHeight : 0)
        baseHeight += Theme.spacingM * 2
        let listHeight = notificationList.listContentHeight
        if (NotificationService.groupedNotifications.length === 0)
          listHeight = 200
        baseHeight += Math.min(listHeight, 600)
        return Math.max(300, Math.min(baseHeight, root.screen ? root.screen.height * 0.8 : Screen.height * 0.8))
      }
      
      color: Theme.popupBackground()
      radius: Theme.cornerRadius
      border.color: Qt.rgba(Theme.outline.r, Theme.outline.g,
                            Theme.outline.b, 0.08)
      border.width: 1
      focus: true

      Component.onCompleted: {
        if (root.shouldBeVisible)
          forceActiveFocus()
      }

      Keys.onPressed: function(event) {
        keyboardController.handleKey(event)
      }

      Connections {
        function onShouldBeVisibleChanged() {
          if (root.shouldBeVisible)
            Qt.callLater(function () {
              notificationContent.forceActiveFocus()
            })
          else
            notificationContent.focus = false
        }
        target: root
      }

      FocusScope {
        id: contentColumn

        anchors.fill: parent
        anchors.margins: Theme.spacingL
        focus: true
        
        Column {
          id: contentColumnInner
          anchors.fill: parent
          spacing: Theme.spacingM

          NotificationHeader {
            id: notificationHeader
            keyboardController: keyboardController
          }
          
          NotificationSettings {
            id: notificationSettings
            expanded: notificationHeader.showSettings
          }

          KeyboardNavigatedNotificationList {
            id: notificationList

            width: parent.width
            height: parent.height - notificationHeader.height - notificationSettings.height - contentColumnInner.spacing * 2
            
            Component.onCompleted: {
              if (keyboardController && notificationList) {
                keyboardController.listView = notificationList
                notificationList.keyboardController = keyboardController
              }
            }
          }
        }
      }

      NotificationKeyboardHints {
        id: keyboardHints
        anchors.bottom: parent.bottom
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.margins: Theme.spacingL
        showHints: keyboardController.showKeyboardHints
        z: 200
      }

      Behavior on implicitHeight {
        NumberAnimation {
          duration: Anims.durShort
          easing.type: Easing.BezierSpline
          easing.bezierCurve: Anims.emphasized
        }
      }
    }
  }
}