fix(clipboard): restore Save button targets in editor

- Original PR #1916 by @nabaco

quickshell/Common/SettingsData.qml

@@ -688,6 +688,7 @@ Singleton {
     property int notificationTimeoutNormal: 5000
     property int notificationTimeoutCritical: 0
     property bool notificationCompactMode: false
+    property bool notificationDedupeEnabled: true
     property int notificationPopupPosition: SettingsData.Position.Top
     property int notificationAnimationSpeed: SettingsData.AnimationSpeed.Short
     property int notificationCustomAnimationDuration: 400

quickshell/Common/settings/SettingsSpec.js

@@ -399,6 +399,7 @@ var SPEC = {
     notificationTimeoutNormal: { def: 5000 },
     notificationTimeoutCritical: { def: 0 },
     notificationCompactMode: { def: false },
+    notificationDedupeEnabled: { def: true },
     notificationPopupPosition: { def: 0 },
     notificationAnimationSpeed: { def: 1 },
     notificationCustomAnimationDuration: { def: 400 },

quickshell/Modals/Clipboard/ClipboardContent.qml

@@ -145,6 +145,7 @@ Item {
                 onDeleteRequested: clipboardContent.modal.deleteEntry(modelData)
                 onPinRequested: clipboardContent.modal.pinEntry(modelData)
                 onUnpinRequested: clipboardContent.modal.unpinEntry(modelData)
+                onEditRequested: clipboardContent.modal.editEntry(modelData)
             }
         }
 
@@ -204,6 +205,7 @@ Item {
                 onDeleteRequested: clipboardContent.modal.deletePinnedEntry(modelData)
                 onPinRequested: clipboardContent.modal.pinEntry(modelData)
                 onUnpinRequested: clipboardContent.modal.unpinEntry(modelData)
+                onEditRequested: clipboardContent.modal.editEntry(modelData)
             }
         }
 

quickshell/Modals/Clipboard/ClipboardEditor.qml

@@ -0,0 +1,519 @@
+pragma ComponentBehavior: Bound
+
+import QtQuick
+import QtQuick.Controls
+import qs.Common
+import qs.Services
+import qs.Widgets
+
+Item {
+    id: root
+
+    required property var modal
+    property var keyController: null
+
+    property var entry: null
+    property string editorText: ""
+
+    function decodeEntryData(data) {
+        if (!data) {
+            return "";
+        }
+        if (typeof data !== "string") {
+            return String(data);
+        }
+
+        const sanitized = data.replace(/\s+/g, "");
+        if (sanitized.length === 0) {
+            return "";
+        }
+
+        try {
+            const chars = new Array(sanitized.length);
+            for (let i = 0; i < sanitized.length; i++) {
+                chars[i] = sanitized.charAt(i);
+            }
+
+            let buffer = null;
+            if (typeof Qt !== "undefined" && typeof Qt.atob === "function") {
+                buffer = Qt.atob(chars);
+            } else if (typeof atob === "function") {
+                const binary = atob(sanitized);
+                const bytes = new Uint8Array(binary.length);
+                for (let i = 0; i < binary.length; i++) {
+                    bytes[i] = binary.charCodeAt(i);
+                }
+                buffer = bytes.buffer;
+            }
+            if (!buffer || buffer.byteLength === 0) {
+                return data;
+            }
+
+            const bytes = new Uint8Array(buffer);
+            let binary = "";
+            for (let i = 0; i < bytes.length; i++) {
+                binary += String.fromCharCode(bytes[i]);
+            }
+
+            try {
+                return decodeURIComponent(escape(binary));
+            } catch (e) {
+                return binary;
+            }
+        } catch (e) {
+            return data;
+        }
+    }
+
+    function setEntry(newEntry) {
+        entry = newEntry;
+        editorText = newEntry?.text ?? newEntry?.preview ?? "";
+        if (editField) {
+            editField.text = editorText;
+        }
+        Qt.callLater(function () {
+            if (editField) {
+                editField.forceActiveFocus();
+            }
+        });
+
+        if (!newEntry || newEntry.isImage) {
+            return;
+        }
+
+        const requestedId = newEntry.id;
+        DMSService.sendRequest("clipboard.getEntry", {
+            "id": requestedId
+        }, function (response) {
+            if (response.error) {
+                return;
+            }
+            if (!root.entry || root.entry.id !== requestedId) {
+                return;
+            }
+            const result = response.result;
+            let fullText = "";
+            if (result?.data) {
+                fullText = root.decodeEntryData(result.data);
+            } else {
+                fullText = result?.preview ?? "";
+            }
+
+            if (!fullText || fullText.length === 0) {
+                return;
+            }
+            root.editorText = fullText;
+            if (editField) {
+                editField.text = fullText;
+            }
+        });
+    }
+
+    function saveEntry(action) {
+        const saveAction = action ?? "history";
+        DMSService.sendRequest("clipboard.copy", {
+            "text": root.editorText
+        }, function (response) {
+            if (response.error) {
+                ToastService.showError(I18n.tr("Failed to update clipboard"));
+                return;
+            }
+            if (saveAction === "history") {
+                modal.mode = "history";
+                Qt.callLater(function () {
+                    ClipboardService.reset();
+                    ClipboardService.refresh();
+                    if (keyController) {
+                        keyController.reset();
+                    }
+                });
+                return;
+            }
+            if (saveAction === "close") {
+                modal.hide();
+                return;
+            }
+            if (saveAction === "paste") {
+                ClipboardService.pasteClipboard(modal.hide);
+            }
+        });
+    }
+
+    function positionSaveMenu() {
+        saveMenu.width = Math.max(saveMenuColumn.implicitWidth + saveMenu.padding * 2, saveButton.width);
+        const pos = saveButton.mapToItem(Overlay.overlay, 0, 0);
+        const popupW = saveMenu.width;
+        const popupH = saveMenu.height;
+        const overlayW = Overlay.overlay.width;
+        const overlayH = Overlay.overlay.height;
+
+        let x = pos.x + (saveButton.width - popupW) / 2;
+        let y = pos.y + saveButton.height + 4;
+        if (y + popupH > overlayH) {
+            y = pos.y - popupH - 4;
+        }
+
+        x = Math.max(8, Math.min(x, overlayW - popupW - 8));
+        y = Math.max(8, y);
+
+        saveMenu.x = x;
+        saveMenu.y = y;
+    }
+
+    function toggleSaveMenu() {
+        if (saveMenu.visible) {
+            saveMenu.close();
+            return;
+        }
+        saveMenu.open();
+        positionSaveMenu();
+        Qt.callLater(positionSaveMenu);
+    }
+
+    Shortcut {
+        sequences: ["Escape"]
+        enabled: modal.mode === "editor"
+        onActivated: modal.mode = "history"
+    }
+
+    Column {
+        anchors.fill: parent
+        anchors.margins: Theme.spacingM
+        spacing: Theme.spacingM
+
+        Item {
+            id: editorHeader
+            width: parent.width
+            height: ClipboardConstants.headerHeight
+
+            DankActionButton {
+                iconName: "arrow_back"
+                iconSize: Theme.iconSize - 4
+                iconColor: Theme.surfaceText
+                anchors.left: parent.left
+                anchors.verticalCenter: parent.verticalCenter
+                onClicked: modal.mode = "history"
+            }
+
+            StyledText {
+                text: I18n.tr("Edit Clipboard")
+                font.pixelSize: Theme.fontSizeLarge
+                color: Theme.surfaceText
+                font.weight: Font.Medium
+                anchors.centerIn: parent
+            }
+
+            DankActionButton {
+                iconName: "close"
+                iconSize: Theme.iconSize - 4
+                iconColor: Theme.surfaceText
+                anchors.right: parent.right
+                anchors.verticalCenter: parent.verticalCenter
+                onClicked: modal.mode = "history"
+            }
+        }
+
+        StyledRect {
+            id: editFieldContainer
+            width: parent.width
+            height: Math.max(Theme.fontSizeMedium * 8, parent.height - editorHeader.height - editorActions.height - Theme.spacingM * 2)
+            radius: Theme.cornerRadius
+            color: Theme.withAlpha(Theme.surfaceContainerHigh, Theme.popupTransparency)
+            border.color: editField.activeFocus ? Theme.primary : Theme.outlineMedium
+            border.width: editField.activeFocus ? 2 : 1
+            clip: true
+
+            DankIcon {
+                id: editIcon
+                name: "edit"
+                size: Theme.iconSize
+                color: editField.activeFocus ? Theme.primary : Theme.surfaceVariantText
+                anchors.left: parent.left
+                anchors.leftMargin: Theme.spacingM
+                anchors.top: parent.top
+                anchors.topMargin: Theme.spacingM
+            }
+
+            DankFlickable {
+                id: editScroll
+                anchors.left: editIcon.right
+                anchors.leftMargin: Theme.spacingS
+                anchors.right: parent.right
+                anchors.top: parent.top
+                anchors.bottom: parent.bottom
+                anchors.rightMargin: Theme.spacingM
+                anchors.topMargin: Theme.spacingS
+                anchors.bottomMargin: Theme.spacingS
+                clip: true
+                contentWidth: width
+                contentHeight: editField.height
+
+                TextEdit {
+                    id: editField
+                    width: editScroll.width
+                    height: Math.max(editScroll.height, contentHeight)
+                    text: root.editorText
+                    font.pixelSize: Theme.fontSizeMedium
+                    color: Theme.surfaceText
+                    wrapMode: TextEdit.Wrap
+                    selectByMouse: true
+                    onTextChanged: root.editorText = text
+                    Keys.onPressed: function (event) {
+                        const hasCtrl = (event.modifiers & Qt.ControlModifier) !== 0;
+                        const hasShift = (event.modifiers & Qt.ShiftModifier) !== 0;
+
+                        if (hasCtrl && event.key === Qt.Key_S) {
+                            root.saveEntry(hasShift ? "close" : "history");
+                            event.accepted = true;
+                            return;
+                        }
+                        if (hasCtrl && hasShift && event.key === Qt.Key_V) {
+                            root.saveEntry("paste");
+                            event.accepted = true;
+                            return;
+                        }
+                    }
+                }
+            }
+
+            StyledText {
+                text: I18n.tr("Edit clipboard text")
+                font.pixelSize: Theme.fontSizeMedium
+                color: Theme.outlineButton
+                anchors.left: editScroll.left
+                anchors.right: editScroll.right
+                anchors.top: editScroll.top
+                anchors.bottom: editScroll.bottom
+                visible: editField.text.length === 0 && !editField.activeFocus
+                wrapMode: Text.WordWrap
+            }
+        }
+
+        Row {
+            id: editorActions
+            width: parent.width
+            spacing: Theme.spacingS
+
+            Item {
+                id: buttonSpacer
+                width: Math.max(0, parent.width - cancelButton.width - saveButton.width - Theme.spacingS)
+                height: 1
+            }
+
+            DankButton {
+                id: cancelButton
+                text: I18n.tr("Cancel")
+                backgroundColor: Theme.surfaceContainerHigh
+                textColor: Theme.surfaceText
+                onClicked: modal.mode = "history"
+            }
+
+            Item {
+                id: saveButton
+
+                readonly property int buttonHeight: cancelButton.buttonHeight
+                readonly property int arrowWidth: Theme.iconSizeLarge
+
+                width: cancelButton.width
+                height: buttonHeight
+
+                Rectangle {
+                    anchors.fill: parent
+                    radius: Theme.cornerRadius
+                    color: Theme.primary
+                }
+
+                Item {
+                    id: saveMainArea
+                    anchors.left: parent.left
+                    anchors.right: saveArrowArea.left
+                    anchors.top: parent.top
+                    anchors.bottom: parent.bottom
+                }
+
+                StyledText {
+                    text: I18n.tr("Save")
+                    font.pixelSize: Theme.fontSizeMedium
+                    font.weight: Font.Medium
+                    color: Theme.onPrimary
+                    anchors.centerIn: saveMainArea
+                }
+
+                Item {
+                    id: saveArrowArea
+                    width: saveButton.arrowWidth
+                    anchors.right: parent.right
+                    anchors.top: parent.top
+                    anchors.bottom: parent.bottom
+                }
+
+                Rectangle {
+                    width: 1
+                    height: parent.height - cancelButton.horizontalPadding
+                    color: Theme.withAlpha(Theme.onPrimary, 0.2)
+                    anchors.right: saveArrowArea.left
+                    anchors.verticalCenter: parent.verticalCenter
+                }
+
+                DankIcon {
+                    name: saveMenu.visible ? "expand_less" : "expand_more"
+                    size: Theme.iconSizeSmall
+                    color: Theme.onPrimary
+                    anchors.centerIn: saveArrowArea
+                }
+
+                StateLayer {
+                    z: 1
+                    anchors.fill: saveMainArea
+                    stateColor: Theme.onPrimary
+                    onClicked: root.saveEntry("history")
+                }
+
+                StateLayer {
+                    z: 1
+                    anchors.fill: saveArrowArea
+                    stateColor: Theme.onPrimary
+                    onClicked: root.toggleSaveMenu()
+                }
+            }
+        }
+
+        Popup {
+            id: saveMenu
+            parent: Overlay.overlay
+            padding: Theme.spacingM
+            modal: true
+            dim: false
+            focus: true
+            closePolicy: Popup.CloseOnEscape | Popup.CloseOnPressOutside
+
+            background: StyledRect {
+                radius: Theme.cornerRadius
+                color: Theme.surfaceContainer
+                border.color: Theme.outlineMedium
+                border.width: 1
+            }
+
+            contentItem: Column {
+                id: saveMenuColumn
+                spacing: Theme.spacingXS
+
+                StyledRect {
+                    implicitWidth: saveMenuRow.implicitWidth + Theme.spacingS * 2
+                    implicitHeight: saveMenuRow.implicitHeight + Theme.spacingS * 2
+                    radius: Theme.cornerRadius
+                    color: saveMenuSaveArea.containsMouse ? Theme.surfaceVariant : "transparent"
+
+                    Row {
+                        id: saveMenuRow
+                        anchors.left: parent.left
+                        anchors.leftMargin: Theme.spacingS
+                        anchors.verticalCenter: parent.verticalCenter
+                        spacing: Theme.spacingS
+
+                        DankIcon {
+                            name: "save"
+                            size: Theme.iconSizeSmall
+                            color: Theme.surfaceText
+                        }
+
+                        StyledText {
+                            text: I18n.tr("Save")
+                            font.pixelSize: Theme.fontSizeMedium
+                            color: Theme.surfaceText
+                        }
+                    }
+
+                    MouseArea {
+                        id: saveMenuSaveArea
+                        anchors.fill: parent
+                        hoverEnabled: true
+                        cursorShape: Qt.PointingHandCursor
+                        onClicked: {
+                            saveMenu.close();
+                            root.saveEntry("history");
+                        }
+                    }
+                }
+
+                StyledRect {
+                    implicitWidth: saveMenuCloseRow.implicitWidth + Theme.spacingS * 2
+                    implicitHeight: saveMenuCloseRow.implicitHeight + Theme.spacingS * 2
+                    radius: Theme.cornerRadius
+                    color: saveMenuCloseArea.containsMouse ? Theme.surfaceVariant : "transparent"
+
+                    Row {
+                        id: saveMenuCloseRow
+                        anchors.left: parent.left
+                        anchors.leftMargin: Theme.spacingS
+                        anchors.verticalCenter: parent.verticalCenter
+                        spacing: Theme.spacingS
+
+                        DankIcon {
+                            name: "close"
+                            size: Theme.iconSizeSmall
+                            color: Theme.surfaceText
+                        }
+
+                        StyledText {
+                            text: I18n.tr("Save and close")
+                            font.pixelSize: Theme.fontSizeMedium
+                            color: Theme.surfaceText
+                        }
+                    }
+
+                    MouseArea {
+                        id: saveMenuCloseArea
+                        anchors.fill: parent
+                        hoverEnabled: true
+                        cursorShape: Qt.PointingHandCursor
+                        onClicked: {
+                            saveMenu.close();
+                            root.saveEntry("close");
+                        }
+                    }
+                }
+
+                StyledRect {
+                    implicitWidth: saveMenuPasteRow.implicitWidth + Theme.spacingS * 2
+                    implicitHeight: saveMenuPasteRow.implicitHeight + Theme.spacingS * 2
+                    radius: Theme.cornerRadius
+                    color: saveMenuPasteArea.containsMouse ? Theme.surfaceVariant : "transparent"
+                    opacity: modal.wtypeAvailable ? 1 : 0.5
+
+                    Row {
+                        id: saveMenuPasteRow
+                        anchors.left: parent.left
+                        anchors.leftMargin: Theme.spacingS
+                        anchors.verticalCenter: parent.verticalCenter
+                        spacing: Theme.spacingS
+
+                        DankIcon {
+                            name: "content_paste"
+                            size: Theme.iconSizeSmall
+                            color: Theme.surfaceText
+                        }
+
+                        StyledText {
+                            text: I18n.tr("Save and paste")
+                            font.pixelSize: Theme.fontSizeMedium
+                            color: Theme.surfaceText
+                        }
+                    }
+
+                    MouseArea {
+                        id: saveMenuPasteArea
+                        anchors.fill: parent
+                        hoverEnabled: true
+                        enabled: modal.wtypeAvailable
+                        cursorShape: enabled ? Qt.PointingHandCursor : Qt.ArrowCursor
+                        onClicked: {
+                            saveMenu.close();
+                            root.saveEntry("paste");
+                        }
+                    }
+                }
+            }
+        }
+    }
+}

quickshell/Modals/Clipboard/ClipboardEntry.qml

@@ -17,6 +17,7 @@ Rectangle {
     signal deleteRequested
     signal pinRequested
     signal unpinRequested
+    signal editRequested
 
     readonly property string entryType: modal ? modal.getEntryType(entry) : "text"
     readonly property string entryPreview: modal ? modal.getEntryPreview(entry) : ""
@@ -70,6 +71,20 @@ Rectangle {
             onClicked: entry.pinned ? unpinRequested() : pinRequested()
         }
 
+        DankActionButton {
+            iconName: "edit"
+            iconSize: Theme.iconSize - 6
+            iconColor: Theme.surfaceText
+
+            onClicked: {
+                if (entryType === "image") {
+                    // TODO - forward to editing software
+                } else {
+                    editRequested();
+                }
+            }
+        }
+
         DankActionButton {
             iconName: "close"
             iconSize: Theme.iconSize - 6
@@ -142,8 +157,11 @@ Rectangle {
 
     MouseArea {
         id: mouseArea
-        anchors.fill: parent
-        anchors.rightMargin: 80
+        anchors.left: parent.left
+        anchors.right: actionButtons.left
+        anchors.rightMargin: Theme.spacingS
+        anchors.top: parent.top
+        anchors.bottom: parent.bottom
         hoverEnabled: true
         cursorShape: Qt.PointingHandCursor
         onPressed: mouse => {

quickshell/Modals/Clipboard/ClipboardHistoryModal.qml

@@ -43,6 +43,18 @@ DankModal {
         service: ClipboardService
     }
 
+    property string mode: "history"
+    onModeChanged: {
+        if (mode !== "history") {
+            return;
+        }
+        Qt.callLater(function () {
+            if (contentLoader.item?.searchField) {
+                contentLoader.item.searchField.forceActiveFocus();
+            }
+        });
+    }
+
     function updateFilteredModel() {
         ClipboardService.updateFilteredModel();
     }
@@ -61,6 +73,7 @@ DankModal {
 
     function show() {
         open();
+        mode = "history";
         activeImageLoads = 0;
         shouldHaveFocus = true;
         ClipboardService.reset();
@@ -130,6 +143,21 @@ DankModal {
         return ClipboardService.getEntryType(entry);
     }
 
+    function editEntry(entry) {
+        if (!entry) {
+            return;
+        }
+        if (entry.isImage) {
+            return;
+        }
+        const editor = contentLoader.item?.editorView;
+        if (!editor) {
+            return;
+        }
+        editor.setEntry(entry);
+        mode = "editor";
+    }
+
     visible: false
     modalWidth: ClipboardConstants.modalWidth
     modalHeight: ClipboardConstants.modalHeight
@@ -138,6 +166,7 @@ DankModal {
     borderColor: Theme.outlineMedium
     borderWidth: 1
     enableShadow: true
+    closeOnEscapeKey: mode !== "editor"
     onBackgroundClicked: hide()
     modalFocusScope.Keys.onPressed: function (event) {
         keyboardController.handleKey(event);
@@ -174,9 +203,109 @@ DankModal {
     property var confirmDialog: clearConfirmDialog
 
     clipboardContent: Component {
-        ClipboardContent {
-            modal: clipboardHistoryModal
-            clearConfirmDialog: clipboardHistoryModal.confirmDialog
+        Item {
+            id: viewContainer
+
+            property alias editorView: editorView
+            property alias searchField: historyContent.searchField
+
+            anchors.fill: parent
+
+            Item {
+                id: historyView
+
+                anchors.fill: parent
+                opacity: 1
+                scale: 1
+                visible: opacity > 0.01
+                enabled: clipboardHistoryModal.mode === "history"
+
+                ClipboardContent {
+                    id: historyContent
+                    anchors.fill: parent
+                    modal: clipboardHistoryModal
+                    clearConfirmDialog: clipboardHistoryModal.confirmDialog
+                }
+            }
+
+            ClipboardEditor {
+                id: editorView
+
+                anchors.fill: parent
+                opacity: 0
+                scale: 0.98
+                visible: opacity > 0.01
+                enabled: clipboardHistoryModal.mode === "editor"
+                focus: clipboardHistoryModal.mode === "editor"
+                modal: clipboardHistoryModal
+                keyController: keyboardController
+            }
+
+            states: [
+                State {
+                    name: "history"
+                    when: clipboardHistoryModal.mode === "history"
+                    PropertyChanges {
+                        target: historyView
+                        opacity: 1
+                        scale: 1
+                    }
+                    PropertyChanges {
+                        target: editorView
+                        opacity: 0
+                        scale: 0.98
+                    }
+                },
+                State {
+                    name: "editor"
+                    when: clipboardHistoryModal.mode === "editor"
+                    PropertyChanges {
+                        target: historyView
+                        opacity: 0
+                        scale: 0.98
+                    }
+                    PropertyChanges {
+                        target: editorView
+                        opacity: 1
+                        scale: 1
+                    }
+                }
+            ]
+
+            transitions: [
+                Transition {
+                    from: "history"
+                    to: "editor"
+                    ParallelAnimation {
+                        NumberAnimation {
+                            property: "opacity"
+                            duration: Theme.shortDuration
+                            easing.type: Theme.standardEasing
+                        }
+                        NumberAnimation {
+                            property: "scale"
+                            duration: Theme.shortDuration
+                            easing.type: Theme.emphasizedEasing
+                        }
+                    }
+                },
+                Transition {
+                    from: "editor"
+                    to: "history"
+                    ParallelAnimation {
+                        NumberAnimation {
+                            property: "opacity"
+                            duration: Theme.shortDuration
+                            easing.type: Theme.standardEasing
+                        }
+                        NumberAnimation {
+                            property: "scale"
+                            duration: Theme.shortDuration
+                            easing.type: Theme.emphasizedEasing
+                        }
+                    }
+                }
+            ]
         }
     }
 }

quickshell/Modals/Clipboard/ClipboardKeyboardController.qml

@@ -66,7 +66,24 @@ QtObject {
         }
     }
 
+    function editSelected() {
+        const entries = modal.activeTab === "saved" ? ClipboardService.pinnedEntries : ClipboardService.unpinnedEntries;
+        if (!entries || entries.length === 0) {
+            return;
+        }
+        const index = ClipboardService.selectedIndex >= 0 && ClipboardService.selectedIndex < entries.length ? ClipboardService.selectedIndex : 0;
+        modal.editEntry(entries[index]);
+    }
+
     function handleKey(event) {
+        if (modal.mode === "editor") {
+            if (event.key === Qt.Key_Escape) {
+                modal.mode = "history";
+                event.accepted = true;
+            }
+            return;
+        }
+
         switch (event.key) {
         case Qt.Key_Escape:
             if (ClipboardService.keyboardNavigationActive) {
@@ -152,6 +169,10 @@ QtObject {
                     event.accepted = true;
                 }
                 return;
+            case Qt.Key_E:
+                editSelected();
+                event.accepted = true;
+                return;
             }
         }
 

quickshell/Modals/Clipboard/ClipboardKeyboardHints.qml

@@ -10,7 +10,7 @@ Rectangle {
     readonly property string hintsText: {
         if (!wtypeAvailable)
             return I18n.tr("Ctrl+Tab: Switch Tab • Ctrl+S: Pin/Unpin • Shift+Del: Clear All • Esc: Close");
-        return enterToPaste ? I18n.tr("Ctrl+Tab: Switch Tab • Ctrl+S: Pin/Unpin • Shift+Enter: Copy • Shift+Del: Clear All • Esc: Close", "Keyboard hints when enter-to-paste is enabled") : I18n.tr("Ctrl+Tab: Switch Tab • Ctrl+S: Pin/Unpin • Shift+Enter: Paste • Shift+Del: Clear All • Esc: Close");
+        return enterToPaste ? I18n.tr("Ctrl+Tab: Switch Tabs • Ctrl+S: Pin/Unpin • Shift+Enter: Copy • Shift+Del: Clear All • F10: Help • Esc: Close", "Keyboard hints when enter-to-paste is enabled") : I18n.tr("Ctrl+Tab: Switch Tabs • Ctrl+S: Pin/Unpin • Shift+Enter: Paste • Shift+Del: Clear All • F10: Help • Esc: Close");
     }
 
     height: ClipboardConstants.keyboardHintsHeight
@@ -22,13 +22,17 @@ Rectangle {
     z: 100
 
     Column {
+        width: parent.width - Theme.spacingL * 2
         anchors.centerIn: parent
         spacing: 2
 
         StyledText {
-            text: keyboardHints.enterToPaste ? I18n.tr("↑/↓: Navigate • Enter: Paste • Del: Delete • F10: Help", "Keyboard hints when enter-to-paste is enabled") : I18n.tr("↑/↓: Navigate • Enter/Ctrl+C: Copy • Del: Delete • F10: Help")
+            text: keyboardHints.enterToPaste ? I18n.tr("↑/↓: Navigate • Enter: Paste • Ctrl+C: Copy • Del: Delete • Ctrl+E: Edit • Ctrl+S: Pin/Unpin • F10: Help", "Keyboard hints when enter-to-paste is enabled") : I18n.tr("↑/↓: Navigate • Enter/Ctrl+C: Copy • Del: Delete • Ctrl+E: Edit • Ctrl+S: Pin/Unpin • F10: Help")
             font.pixelSize: Theme.fontSizeSmall
             color: Theme.surfaceText
+            width: parent.width
+            wrapMode: Text.WordWrap
+            horizontalAlignment: Text.AlignHCenter
             anchors.horizontalCenter: parent.horizontalCenter
         }
 
@@ -36,6 +40,9 @@ Rectangle {
             text: keyboardHints.hintsText
             font.pixelSize: Theme.fontSizeSmall
             color: Theme.surfaceText
+            width: parent.width
+            wrapMode: Text.WordWrap
+            horizontalAlignment: Text.AlignHCenter
             anchors.horizontalCenter: parent.horizontalCenter
         }
     }

quickshell/Modules/Notifications/Center/HistoryNotificationCard.qml

@@ -182,26 +182,30 @@ Rectangle {
                 Row {
                     width: parent.width
                     spacing: Theme.spacingXS
-                    readonly property real reservedTrailingWidth: historySeparator.implicitWidth + Math.max(historyTimeText.implicitWidth, 72) + spacing
 
-                    StyledText {
-                        id: historyTitleText
-                        width: Math.min(implicitWidth, Math.max(0, parent.width - parent.reservedTrailingWidth))
-                        text: {
-                            let title = historyItem.summary || "";
-                            const appName = historyItem.appName || "";
-                            const prefix = appName + " • ";
-                            if (appName && title.toLowerCase().startsWith(prefix.toLowerCase())) {
-                                title = title.substring(prefix.length);
+                    Item {
+                        width: Math.max(0, parent.width - historySeparator.implicitWidth - Math.max(historyTimeText.implicitWidth, 72) - parent.spacing * 2)
+                        height: historyTitleText.implicitHeight
+                        visible: historyTitleText.text.length > 0
+
+                        StyledText {
+                            id: historyTitleText
+                            anchors.fill: parent
+                            text: {
+                                let title = historyItem.summary || "";
+                                const appName = historyItem.appName || "";
+                                const prefix = appName + " • ";
+                                if (appName && title.toLowerCase().startsWith(prefix.toLowerCase())) {
+                                    title = title.substring(prefix.length);
+                                }
+                                return title;
                             }
-                            return title;
+                            color: Theme.surfaceText
+                            font.pixelSize: Theme.fontSizeMedium
+                            font.weight: Font.Medium
+                            elide: Text.ElideRight
+                            maximumLineCount: 1
                         }
-                        color: Theme.surfaceText
-                        font.pixelSize: Theme.fontSizeMedium
-                        font.weight: Font.Medium
-                        elide: Text.ElideRight
-                        maximumLineCount: 1
-                        visible: text.length > 0
                     }
                     StyledText {
                         id: historySeparator

quickshell/Modules/Settings/NotificationsTab.qml

@@ -273,6 +273,17 @@ Item {
                     onToggled: checked => SettingsData.set("notificationCompactMode", checked)
                 }
 
+                SettingsToggleRow {
+                    settingKey: "notificationDedupeEnabled"
+                    tags: ["notification", "duplicate", "dedupe", "stack", "coalesce", "repeat"]
+                    text: I18n.tr("Suppress Duplicate Notifications")
+                    description: SettingsData.notificationDedupeEnabled
+                             ? I18n.tr("Identical alerts show as one popup instead of stacking")
+                             : I18n.tr("Identical alerts stack as separate notification cards")
+                    checked: SettingsData.notificationDedupeEnabled
+                    onToggled: checked => SettingsData.set("notificationDedupeEnabled", checked)
+                }
+
                 SettingsToggleRow {
                     settingKey: "notificationPopupShadowEnabled"
                     tags: ["notification", "popup", "shadow", "radius", "rounded"]

quickshell/Services/ClipboardService.qml

@@ -240,6 +240,17 @@ Singleton {
         });
     }
 
+    function pasteClipboard(closeCallback) {
+        if (!wtypeAvailable) {
+            ToastService.showError(I18n.tr("wtype not available - install wtype for paste support"));
+            return;
+        }
+        if (closeCallback) {
+            closeCallback();
+        }
+        pasteTimer.start();
+    }
+
     function pasteEntry(entry, closeCallback) {
         if (!wtypeAvailable) {
             ToastService.showError(I18n.tr("wtype not available - install wtype for paste support"));

quickshell/Services/NotificationService.qml

@@ -35,6 +35,8 @@ Singleton {
     property int maxIngressPerSecond: 20
     property double _lastIngressSec: 0
     property int _ingressCountThisSec: 0
+    readonly property int notificationDedupBurstMs: 5000
+    property var _recentDedupKeys: []
 
     property var _dismissQueue: []
     property int _dismissBatchSize: 8
@@ -291,18 +293,58 @@ Singleton {
         return Date.now() / 1000.0;
     }
 
+    function _normalizeDedupText(text) {
+        if (!text)
+            return "";
+        let normalized = text.toString();
+        normalized = normalized.replace(/<img\b[^>]*>/gi, "");
+        normalized = normalized.replace(/<[^>]+>/g, "");
+        normalized = normalized.replace(/\s+/g, " ").trim();
+        return normalized.toLowerCase();
+    }
+
+    function _dedupAppId(source) {
+        if (!source)
+            return "";
+        const desktopEntry = (source.desktopEntry || "").toString().trim().toLowerCase();
+        if (desktopEntry)
+            return desktopEntry;
+        return (source.appName || "").toString().trim().toLowerCase();
+    }
+
     function _notificationDedupKey(source) {
         if (!source)
             return "";
-        const app = (source.appName || source.desktopEntry || "").toString();
-        const summary = (source.summary || "").toString();
-        const body = (source.body || "").toString();
+        const app = _dedupAppId(source);
+        const summary = _normalizeDedupText(source.summary);
+        const body = _normalizeDedupText(source.body);
         const urgency = typeof source.urgency === "number" ? source.urgency : NotificationUrgency.Normal;
-        const icon = (source.appIcon || "").toString();
         if (!app && !summary && !body)
             return "";
         const sep = "
";
-        return app + sep + summary + sep + body + sep + urgency + sep + icon;
+        return app + sep + summary + sep + body + sep + urgency;
+    }
+
+    function _pruneRecentDedupKeys() {
+        const cutoff = Date.now() - notificationDedupBurstMs;
+        _recentDedupKeys = _recentDedupKeys.filter(entry => entry && entry.atMs >= cutoff);
+    }
+
+    function _hasRecentDuplicate(key) {
+        if (!key)
+            return false;
+        _pruneRecentDedupKeys();
+        return _recentDedupKeys.some(entry => entry && entry.key === key);
+    }
+
+    function _recordDedupKey(key) {
+        if (!key)
+            return;
+        _pruneRecentDedupKeys();
+        _recentDedupKeys.push({
+            "key": key,
+            "atMs": Date.now()
+        });
     }
 
     function _findActiveDuplicate(notif) {
@@ -310,17 +352,14 @@ Singleton {
         if (!key)
             return null;
 
-        for (const w of visibleNotifications) {
+        for (const w of allWrappers) {
             if (!w || !w.notification || !w.popup)
                 continue;
-            if (_notificationDedupKey(w.notification) === key)
-                return w;
-        }
-
-        for (const w of notificationQueue) {
-            if (!w || !w.notification)
+            if (_notificationDedupKey(w.notification) !== key)
                 continue;
-            if (_notificationDedupKey(w.notification) === key)
+            if (visibleNotifications.indexOf(w) !== -1 || notificationQueue.indexOf(w) !== -1)
+                return w;
+            if (w.timer && w.timer.running)
                 return w;
         }
 
@@ -637,14 +676,17 @@ Singleton {
                 return;
             }
 
-            const duplicate = _findActiveDuplicate(notif);
-            if (duplicate) {
-                if (duplicate.timer && duplicate.timer.running)
-                    duplicate.timer.restart();
-                try {
-                    notif.dismiss();
-                } catch (e) {}
-                return;
+            if (SettingsData.notificationDedupeEnabled) {
+                const dedupKey = _notificationDedupKey(notif);
+                const duplicate = _findActiveDuplicate(notif);
+                if (duplicate || _hasRecentDuplicate(dedupKey)) {
+                    if (duplicate && duplicate.timer && duplicate.timer.running)
+                        duplicate.timer.restart();
+                    try {
+                        notif.dismiss();
+                    } catch (e) {}
+                    return;
+                }
             }
 
             if (!_ingressAllowed(policy.urgency)) {
@@ -686,6 +728,9 @@ Singleton {
             });
 
             if (wrapper) {
+                if (SettingsData.notificationDedupeEnabled)
+                    _recordDedupKey(_notificationDedupKey(notif));
+
                 root.allWrappers.push(wrapper);
                 if (shouldKeepInCenter) {
                     root.notifications.push(wrapper);

quickshell/translations/settings_search_index.json

@@ -5807,6 +5807,28 @@
     ],
     "description": "Use smaller notification cards"
   },
+  {
+    "section": "notificationDedupeEnabled",
+    "label": "Suppress Duplicate Notifications",
+    "tabIndex": 17,
+    "category": "Notifications",
+    "keywords": [
+      "alert",
+      "alerts",
+      "coalesce",
+      "dedupe",
+      "duplicate",
+      "duplicates",
+      "messages",
+      "notif",
+      "notification",
+      "notifications",
+      "repeat",
+      "stack",
+      "toast"
+    ],
+    "description": "Control whether identical alerts stack or show as a single popup"
+  },
   {
     "section": "notificationHistorySaveCritical",
     "label": "Critical Priority",